feat: import plugin sources, tests, and CI utils from WasmEdge core

plugins/CMakeLists.txt

@@ -0,0 +1,118 @@
+# SPDX-License-Identifier: Apache-2.0
+# SPDX-FileCopyrightText: 2019-2024 Second State INC
+
+# WASI plug-in: WASI-Crypto proposal.
+if(WASMEDGE_PLUGIN_WASI_CRYPTO)
+  add_subdirectory(wasi_crypto)
+endif()
+
+# WASI plug-in: WASI-Http proposal.
+if(WASMEDGE_PLUGIN_WASI_HTTP)
+  add_subdirectory(wasi_http)
+endif()
+
+# WASI plug-in: WASI-Logging proposal.
+if(WASMEDGE_PLUGIN_WASI_LOGGING)
+  # BUILTIN-PLUGIN: Add the wasi-logging plugin here after the new plugin
+  # architecture is ready in 0.15.0.
+endif()
+
+# WASI plug-in: WASI-NN proposal with backends.
+if(WASMEDGE_PLUGIN_WASI_NN_BACKEND)
+  add_subdirectory(wasi_nn)
+endif()
+
+# WASI plug-in: WASI-Poll proposal.
+if(WASMEDGE_PLUGIN_WASI_POLL)
+  add_subdirectory(wasi_poll)
+endif()
+
+# WasmEdge plug-in: wasm-bpf.
+if(WASMEDGE_PLUGIN_WASM_BPF)
+  # wasm_bpf is currently supported only on Linux systems.
+  if(CMAKE_SYSTEM_NAME MATCHES "Linux")
+    add_subdirectory(wasm_bpf)
+  else()
+    message(WARNING "Only Linux platforms support wasm_bpf plug-in now.")
+  endif()
+endif()
+
+# WasmEdge plug-in: ffmpeg.
+if(WASMEDGE_PLUGIN_FFMPEG)
+  add_subdirectory(wasmedge_ffmpeg)
+endif()
+
+# WasmEdge plug-in: Image.
+if(WASMEDGE_PLUGIN_IMAGE)
+  # wasmedge_image is currently supported only on Linux and macOS.
+  if(CMAKE_SYSTEM_NAME MATCHES "Linux|Darwin")
+    add_subdirectory(wasmedge_image)
+  else()
+    message(WARNING "Only Linux and Darwin platforms support WasmEdge_Image plug-in now.")
+  endif()
+endif()
+
+# WasmEdge plug-in: LLMC.
+if(WASMEDGE_PLUGIN_LLMC)
+  add_subdirectory(wasmedge_llmc)
+endif()
+
+# WasmEdge plug-in: OCR.
+if(WASMEDGE_PLUGIN_OCR)
+  add_subdirectory(wasmedge_ocr)
+endif()
+
+# WasmEdge plug-in: OpenCV-mini.
+if(WASMEDGE_PLUGIN_OPENCVMINI)
+  # wasmedge_opencvmini is currently supported only on Linux and macOS.
+  if(CMAKE_SYSTEM_NAME MATCHES "Linux|Darwin")
+    add_subdirectory(wasmedge_opencvmini)
+  else()
+    message(WARNING "Only Linux and Darwin platforms support WasmEdge_OpenCVMini plug-in now.")
+  endif()
+endif()
+
+# WasmEdge plug-in: Process.
+if(WASMEDGE_PLUGIN_PROCESS)
+  # wasmedge_process is currently supported only on Linux systems.
+  if(CMAKE_SYSTEM_NAME MATCHES "Linux")
+    add_subdirectory(wasmedge_process)
+  else()
+    message(WARNING "Only Linux platforms support WasmEdge_Process plug-in now.")
+  endif()
+endif()
+
+# WasmEdge plug-in: Stable-diffusion.
+if(WASMEDGE_PLUGIN_STABLEDIFFUSION)
+  # wasmedge_stablediffusion is currently supported only on Linux and macOS.
+  if(CMAKE_SYSTEM_NAME MATCHES "Linux|Darwin")
+    add_subdirectory(wasmedge_stablediffusion)
+  else()
+    message(WARNING "Only Linux and Darwin platforms support WasmEdge_StableDiffusion plug-in now.")
+  endif()
+endif()
+
+# WasmEdge plug-in: TensorFlow.
+if(WASMEDGE_PLUGIN_TENSORFLOW)
+  # wasmedge_tensorflow is currently supported only on Linux and macOS.
+  if(CMAKE_SYSTEM_NAME MATCHES "Linux|Darwin")
+    add_subdirectory(wasmedge_tensorflow)
+  else()
+    message(WARNING "Only Linux and Darwin platforms support WasmEdge_Tensorflow plug-in now.")
+  endif()
+endif()
+
+# WasmEdge plug-in: TensorFlow-Lite.
+if(WASMEDGE_PLUGIN_TENSORFLOWLITE)
+  # wasmedge_tensorflowlite is currently supported only on Linux and macOS.
+  if(CMAKE_SYSTEM_NAME MATCHES "Linux|Darwin")
+    add_subdirectory(wasmedge_tensorflowlite)
+  else()
+    message(WARNING "Only Linux and Darwin platforms support WasmEdge_TensorflowLite plug-in now.")
+  endif()
+endif()
+
+# WasmEdge plug-in: zlib.
+if(WASMEDGE_PLUGIN_ZLIB)
+  add_subdirectory(wasmedge_zlib)
+endif()

plugins/wasi_crypto/CMakeLists.txt

@@ -0,0 +1,86 @@
+# SPDX-License-Identifier: Apache-2.0
+# SPDX-FileCopyrightText: 2019-2024 Second State INC
+
+set(OPENSSL_USE_STATIC_LIBS ON)
+find_package(OpenSSL REQUIRED)
+
+wasmedge_add_library(wasmedgePluginWasiCrypto
+  SHARED
+  ctx.cpp
+  asymmetric_common/ctx.cpp
+  asymmetric_common/func.cpp
+  asymmetric_common/keypair.cpp
+  asymmetric_common/module.cpp
+  asymmetric_common/publickey.cpp
+  asymmetric_common/secretkey.cpp
+  common/array_output.cpp
+  common/ctx.cpp
+  common/func.cpp
+  common/module.cpp
+  common/options.cpp
+  kx/ctx.cpp
+  kx/dh/ecdsa.cpp
+  kx/dh/x25519.cpp
+  kx/func.cpp
+  kx/kx.cpp
+  kx/module.cpp
+  kx/options.cpp
+  signatures/ctx.cpp
+  signatures/ecdsa.cpp
+  signatures/eddsa.cpp
+  signatures/func.cpp
+  signatures/module.cpp
+  signatures/options.cpp
+  signatures/rsa.cpp
+  signatures/signatures.cpp
+  signatures/signstate.cpp
+  signatures/verificationstate.cpp
+  symmetric/aeads.cpp
+  symmetric/ctx.cpp
+  symmetric/func.cpp
+  symmetric/hash.cpp
+  symmetric/kdf.cpp
+  symmetric/key.cpp
+  symmetric/mac.cpp
+  symmetric/module.cpp
+  symmetric/options.cpp
+  symmetric/state.cpp
+  symmetric/tag.cpp
+  utils/evp_wrapper.cpp
+  utils/hostfunction.cpp
+)
+
+target_compile_options(wasmedgePluginWasiCrypto
+  PUBLIC
+  -DWASMEDGE_PLUGIN
+  -DOPENSSL_API_COMPAT=0x10100000L
+)
+
+target_include_directories(wasmedgePluginWasiCrypto
+  PUBLIC
+  $<TARGET_PROPERTY:wasmedgePlugin,INCLUDE_DIRECTORIES>
+  ${CMAKE_CURRENT_SOURCE_DIR}
+  ${PROJECT_SOURCE_DIR}/thirdparty
+)
+
+target_link_libraries(wasmedgePluginWasiCrypto
+  PUBLIC
+  OpenSSL::Crypto
+)
+if(WASMEDGE_LINK_PLUGINS_STATIC)
+  target_link_libraries(wasmedgePluginWasiCrypto
+    PRIVATE
+    wasmedgeCAPI
+  )
+else()
+  target_link_libraries(wasmedgePluginWasiCrypto
+    PRIVATE
+    wasmedge_shared
+  )
+endif()
+
+install(
+  TARGETS wasmedgePluginWasiCrypto
+  DESTINATION ${CMAKE_INSTALL_LIBDIR}/wasmedge
+  COMPONENT WasmEdge
+)